qbar/src/QBar/Theme.hs

+module QBar.Theme (
+  Theme(..),
+  ThemedBlockOutput(..),
+  ThemedBlockText(..),
+  ThemedBlockTextSegment(..),
+  defaultTheme,
+  findTheme,
+  isAnimated,
+  mkTheme,
+  mkThemedBlockOutput,
+  themeNames,
+  themes,
+  whiteThemedBlockOutput,
+) where
+
+import QBar.BlockOutput
+import QBar.Color
+import QBar.Prelude
+
+import Control.Applicative ((<|>))
+import Control.Lens ((^.))
+import Control.Monad.State.Lazy (State, evalState, get, put)
+import Data.Colour.RGBSpace
+import Data.Colour.RGBSpace.HSV (hsv)
+import Data.HashMap.Lazy qualified as HM
+import Data.Maybe (fromMaybe)
+import Data.Text.Lazy qualified as T
+import Data.Time.Clock.POSIX (getPOSIXTime)
+import Pipes
+
+
+data ThemedBlockOutput = ThemedBlockOutput {
+    _fullText :: ThemedBlockText,
+    _shortText :: Maybe ThemedBlockText,
+    _blockName :: Maybe T.Text
+  }
+  deriving (Eq, Show)
+
+newtype ThemedBlockText = ThemedBlockText [ThemedBlockTextSegment]
+  deriving (Eq, Show)
+instance Semigroup ThemedBlockText where
+  (ThemedBlockText a) <> (ThemedBlockText b) = ThemedBlockText (a <> b)
+instance Monoid ThemedBlockText where
+  mempty = ThemedBlockText []
+
+data ThemedBlockTextSegment = ThemedBlockTextSegment {
+    themedSegmentText :: T.Text,
+    color :: Color,
+    backgroundColor :: Maybe Color
+  }
+  deriving (Eq, Show)
+
+data Theme = StaticTheme StaticTheme | AnimatedTheme AnimatedTheme
+
+type StaticTheme = [BlockOutput] -> [ThemedBlockOutput]
+type SimplifiedTheme = Bool -> Importance -> (Color, Maybe Color)
+type AnimatedTheme = forall r. Pipe [BlockOutput] [ThemedBlockOutput] IO r
+
+isAnimated :: Theme -> Bool
+isAnimated (AnimatedTheme _) = True
+isAnimated _ = False
+
+
+themesList :: [(Text, Theme)]
+themesList = [
+    ("default", defaultTheme),
+    ("rainbow", rainbowTheme)
+  ]
+
+themeNames :: [Text]
+themeNames = map fst themesList
+
+themes :: HM.HashMap Text Theme
+themes = HM.fromList themesList
+
+
+findTheme :: Text -> Either Text Theme
+findTheme themeName = maybe invalidThemeName Right $ HM.lookup themeName themes
+  where
+    invalidThemeName :: Either Text Theme
+    invalidThemeName = Left $ "Invalid theme: " <> themeName
+
+mkTheme :: SimplifiedTheme -> Theme
+mkTheme theming' = StaticTheme $ map themeBlock
+  where
+    themeBlock :: BlockOutput -> ThemedBlockOutput
+    themeBlock block@BlockOutput{_blockName} = ThemedBlockOutput{_fullText = fullText', _shortText = shortText', _blockName}
+      where
+        theming :: SimplifiedTheme
+        theming
+          | block ^. invalid = invalidSimplifiedTheme
+          | otherwise = theming'
+        fullText' :: ThemedBlockText
+        fullText' = themeBlockText theming $ block ^. fullText
+        shortText' :: Maybe ThemedBlockText
+        shortText' = themeBlockText theming <$> block ^. shortText
+    themeBlockText :: SimplifiedTheme -> BlockText -> ThemedBlockText
+    themeBlockText theming (BlockText b) = ThemedBlockText $ themeSegment theming <$> b
+    themeSegment :: SimplifiedTheme -> BlockTextSegment -> ThemedBlockTextSegment
+    themeSegment theming BlockTextSegment {active, importance, segmentText} = mkThemedSegment (theming active importance) segmentText
+    themeSegment theming StyledBlockTextSegment {color, backgroundColor, segmentText} = mkThemedSegment (themedColor, themedBackgroundColor) segmentText
+      where
+        themedColor :: Color
+        themedColor = fromMaybe normalThemedColor color
+        themedBackgroundColor :: Maybe Color
+        themedBackgroundColor = backgroundColor <|> normalThemedBackground
+        (normalThemedColor, normalThemedBackground) = theming False normalImportant
+
+mkThemedBlockOutput :: (Color, Maybe Color) -> Text -> ThemedBlockOutput
+mkThemedBlockOutput color text = ThemedBlockOutput {
+  _fullText = mkThemedText color text,
+  _shortText = Nothing,
+  _blockName = Nothing
+}
+
+mkThemedText :: (Color, Maybe Color) -> Text -> ThemedBlockText
+mkThemedText color text = ThemedBlockText [mkThemedSegment color text]
+
+mkThemedSegment :: (Color, Maybe Color) -> Text -> ThemedBlockTextSegment
+mkThemedSegment (color, backgroundColor) text = ThemedBlockTextSegment{themedSegmentText=text, color, backgroundColor}
+
+whiteThemedBlockOutput :: Text -> ThemedBlockOutput
+whiteThemedBlockOutput = mkThemedBlockOutput (ColorRGB (RGB 1 1 1), Nothing)
+
+invalidColor :: Color
+invalidColor = ColorRGBA (RGB (0x96 / 255) (0x98 / 255) (0x96 / 255)) (0x77 / 255)
+
+invalidSimplifiedTheme :: SimplifiedTheme
+invalidSimplifiedTheme _ _ = (invalidColor, Nothing)
+
+defaultTheme :: Theme
+defaultTheme = mkTheme defaultTheme'
+  where
+    defaultTheme' :: SimplifiedTheme
+    defaultTheme' True (CriticalImportant _) = (ColorRGB (RGB 0 0 0), Just $ ColorRGB (RGB 1 0 0))
+    defaultTheme' False (CriticalImportant _) = (ColorRGB (RGB 0.8 0.15 0.15), Nothing)
+    defaultTheme' True (ErrorImportant _) = (ColorRGB (RGB 1 0.3 0), Nothing)
+    defaultTheme' False (ErrorImportant _) = (ColorRGB (RGB 0.7 0.35 0.2), Nothing)
+    defaultTheme' True (WarnImportant _) = (ColorRGB (RGB 1 0.9 0), Nothing)
+    defaultTheme' False (WarnImportant _) = (ColorRGB (RGB 0.6 0.6 0), Nothing)
+    defaultTheme' True (NormalImportant _) = (ColorRGB (RGB 1 1 1), Nothing)
+    defaultTheme' False (NormalImportant _) = (ColorRGB (RGB (0x96 / 255) (0x98 / 255) (0x96 / 255)), Nothing)
+
+rainbowTheme :: Theme
+rainbowTheme = AnimatedTheme rainbowThemePipe
+  where
+    rainbowThemePipe :: AnimatedTheme
+    rainbowThemePipe = do
+      time <- liftIO $ fromRational . toRational <$> getPOSIXTime
+      yield . rainbowThemePipe' time =<< await
+      rainbowThemePipe
+    rainbowThemePipe' :: Double -> StaticTheme
+    rainbowThemePipe' time blocks = reverse $ evalState (mapM rainbowBlock $ reverse blocks) 0
+      where
+        rainbowBlock :: BlockOutput -> State Integer ThemedBlockOutput
+        rainbowBlock block@BlockOutput{_blockName} = do
+          let text = rawText $ block ^. fullText
+          let chars = reverse . splitToChars $ text
+          coloredChars <- mapM rainbowChar chars
+          let rainbowText = reverse coloredChars
+          return $ ThemedBlockOutput {
+            _blockName,
+            _fullText = ThemedBlockText rainbowText,
+            _shortText = Nothing
+          }
+        rainbowChar :: T.Text -> State Integer ThemedBlockTextSegment
+        rainbowChar char = do
+          color <- nextRainbowColor
+          return $ mkThemedSegment (color, Nothing) $ char
+        nextRainbowColor :: State Integer Color
+        -- nextRainbowColor = state $ \index -> (rainbowColor (fromInteger index), index + 1)
+        nextRainbowColor = do
+          index <- get
+          put $ index + 1
+          return $ rainbowColor (fromInteger index + time * 10)
+        rainbowColor :: Double -> Color
+        rainbowColor position =
+          let hue' = position * 3
+              color = hsv hue' 0.8 1.0
+          in ColorRGB color
+        splitToChars :: T.Text -> [T.Text]
+        splitToChars = splitStringToChars . T.unpack
+        splitStringToChars :: String -> [T.Text]
+        splitStringToChars [] = []
+        splitStringToChars ('&':xs) = splitStringToCharsAmp "&" xs
+        splitStringToChars (x:xs) = T.singleton x : splitStringToChars xs
+        splitStringToCharsAmp :: String -> String -> [T.Text]
+        splitStringToCharsAmp _ [] = []
+        splitStringToCharsAmp acc (';':xs) = T.pack (acc <> ";") : splitStringToChars xs
+        splitStringToCharsAmp acc (x:xs) = splitStringToCharsAmp (acc <> [x]) xs

qbar/src/QBar/Time.hs

+{-# LANGUAGE OverloadedLists #-}
+
+module QBar.Time (
+  HasSleepScheduler(..),
+  Interval(..),
+  SleepScheduler,
+  createSleepScheduler,
+  everyMinute,
+  everyNSeconds,
+  humanReadableInterval,
+  nextIntervalTime,
+  sleepUntil',
+  sleepUntil,
+  sleepUntilInterval',
+  sleepUntilInterval,
+) where
+
+import QBar.Prelude
+
+import Control.Concurrent.Async
+import Control.Concurrent.Event qualified as Event
+import Control.Concurrent.MVar
+import Data.Ord (comparing)
+import Data.SortedList (SortedList, toSortedList, fromSortedList, singleton, partition, insert)
+import Data.Time.Clock (UTCTime, getCurrentTime, diffUTCTime, utctDayTime, addUTCTime)
+
+newtype Interval = IntervalSeconds Integer
+  deriving (Read, Show)
+
+-- |Describes an interval that is run every "n" seconds after midnight.
+everyNSeconds :: Integer -> Interval
+everyNSeconds = IntervalSeconds
+
+-- |Describes an interval that is run every minute.
+everyMinute :: Interval
+everyMinute = IntervalSeconds 60
+
+nextIntervalTime :: MonadIO m => Interval -> m UTCTime
+nextIntervalTime (IntervalSeconds intervalSeconds) = liftIO $ do
+  now <- getCurrentTime
+  let dayTime = utctDayTime now
+  let daySeconds :: Integer = floor dayTime
+  let intervalId = daySeconds `div` intervalSeconds
+  return now {
+    utctDayTime = fromInteger $ (intervalId + 1) * intervalSeconds
+  }
+
+humanReadableInterval :: Interval -> String
+humanReadableInterval (IntervalSeconds i) = show i <> "s"
+
+data SleepScheduler = SleepScheduler (MVar (SortedList ScheduledEvent, [ScheduledEvent])) Event.Event
+data ScheduledEvent = ScheduledEvent {
+  time :: UTCTime,
+  event :: Event.Event,
+  fireOnNegativeTimeJump :: Bool
+} deriving Eq
+instance Ord ScheduledEvent where
+  compare = comparing time
+
+class HasSleepScheduler m where
+  askSleepScheduler :: m SleepScheduler
+
+createSleepScheduler :: MonadIO m => m SleepScheduler
+createSleepScheduler = liftIO $ do
+  scheduler <- SleepScheduler <$> newMVar ([], []) <*> Event.new
+  link =<< async (schedulerThread scheduler)
+  return scheduler
+  where
+    schedulerThread :: SleepScheduler -> IO ()
+    schedulerThread (SleepScheduler eventsMVar trigger) = schedulerThread' =<< getCurrentTime
+      where
+        schedulerThread' :: UTCTime -> IO ()
+        schedulerThread' lastTime = do
+          start <- getCurrentTime
+
+          -- Check for a negative time step (threshold is between 5 and 65 seconds, depending on loop activity)
+          when (start < addUTCTime (fromInteger (-5)) lastTime) $ fireEvents fireOnNegativeTimeJump
+
+          (sortedEvents, _) <- readMVar eventsMVar
+          waitResult <- case fromSortedList sortedEvents of
+            [] -> True <$ Event.wait trigger
+            (ScheduledEvent{time} : _) -> waitForEvent time
+
+          when waitResult $ do
+            now <- getCurrentTime
+            fireEvents (checkEvent now)
+
+          schedulerThread' start
+
+        -- Waits for the next event, with a timeout. A return value of 'False' indicates a timeout occured.
+        waitForEvent :: UTCTime -> IO Bool
+        waitForEvent eventTime = do
+          now <- getCurrentTime
+          let timeUntil = diffUTCTime eventTime now
+          if
+            | timeUntil <= 0 -> return True
+            | timeUntil < 60 -> True <$ Event.waitTimeout trigger (ceiling $ toRational timeUntil * 1000000)
+            -- False indicates a timeout, in which case no events need to be fired
+            | otherwise -> Event.waitTimeout trigger (60 * 1000000)
+
+
+        fireEvents :: (ScheduledEvent -> Bool) -> IO ()
+        fireEvents predicate =
+          modifyMVar_ eventsMVar $ \(hots, colds) -> do
+            let allEvents = hots <> toSortedList colds
+            let (activeEvents, futureEvents) = partition predicate allEvents
+            mapM_ (Event.set . event) activeEvents
+            -- Sleep scheduler thread 'Event' is cleared during 'modifyMVar_' to prevent race conditions.
+            Event.clear trigger
+            return (futureEvents, [])
+
+        -- Predicate to check if an event should be fired.
+        checkEvent :: UTCTime -> ScheduledEvent -> Bool
+        checkEvent now ScheduledEvent{time} = now >= time
+
+
+queueScheduledEvent :: MonadIO m => SleepScheduler -> ScheduledEvent -> m ()
+queueScheduledEvent (SleepScheduler eventsMVar trigger) event@ScheduledEvent{time=eventTime} = liftIO $
+  modifyMVar_ eventsMVar $ \(sorted, unsorted) ->
+    -- Sleep scheduler thread 'Event' is set during 'modifyMVar_' to prevent race conditions.
+    case fromSortedList sorted of
+      [] -> (singleton event, unsorted) <$ Event.set trigger
+      (first : _) ->
+        if eventTime < time first
+          -- Event happens before the first event, so it is inserted at the front of the sorted list and the scheduler thread is notified
+          then (insert event sorted, unsorted) <$ Event.set trigger
+          -- Otherwise it is added to the unsorted pool and will be handled later.
+          else return (sorted, event:unsorted)
+
+
+-- |Suspends the thread until the given time is reached.
+sleepUntil :: (HasSleepScheduler m, MonadIO m) => UTCTime -> m ()
+sleepUntil time = do
+  scheduler <- askSleepScheduler
+  sleepUntil' scheduler time
+
+sleepUntil' :: MonadIO m => SleepScheduler -> UTCTime -> m ()
+sleepUntil' scheduler time = liftIO $ do
+  event <- Event.new
+  queueScheduledEvent scheduler (ScheduledEvent {time, event, fireOnNegativeTimeJump=False})
+  Event.wait event
+
+-- |Suspends the thread until the next time boundary described by 'Interval' is reached. Also returns when the system time jumps backwards.
+sleepUntilInterval :: (HasSleepScheduler m, MonadIO m) => Interval -> m ()
+sleepUntilInterval interval = do
+  scheduler <- askSleepScheduler
+  sleepUntilInterval' scheduler interval
+
+sleepUntilInterval' :: MonadIO m => SleepScheduler -> Interval -> m ()
+sleepUntilInterval' scheduler interval = liftIO $ do
+  event <- Event.new
+  time <- nextIntervalTime interval
+  queueScheduledEvent scheduler (ScheduledEvent {time, event, fireOnNegativeTimeJump=True})
+  Event.wait event

qbar/src/QBar/Utils.hs

+module QBar.Utils (
+  mkBroadcastCacheP,
+  mkBroadcastP,
+  randomIdentifier,
+  signalEventPipe,
+) where
+
+import QBar.Prelude
+
+import Control.Concurrent.Event as Event
+import Control.Concurrent.STM (atomically)
+import Control.Concurrent.STM.TChan
+import Control.Concurrent.STM.TVar
+import Control.Monad (replicateM)
+import Data.Text.Lazy qualified as T
+import Pipes
+import System.Random
+
+-- Pipe that signals an 'Event' after every value that passes through
+signalEventPipe :: MonadIO m => Event.Event -> Pipe a a m r
+signalEventPipe event = forever $ (yield =<< await) >> liftIO (Event.signal event)
+
+randomIdentifier :: MonadIO m => m Text
+randomIdentifier = liftIO $ T.pack <$> replicateM 8 randomCharacter
+  where
+    randomCharacter :: IO Char
+    randomCharacter = do
+      index <- randomRIO (0, T.length alphabet - 1)
+      return $ T.index alphabet index
+    alphabet :: T.Text
+    alphabet = T.pack $ ['A'..'Z'] ++ ['a'..'z'] ++ ['0'..'9']
+
+-- |Creates a pair of consumer and producer. Both can be used multiple times in parallel.
+-- |All values send to a consumer will be sent to all currently running producers.
+mkBroadcastP :: forall a. IO (Consumer a IO (), Producer a IO ())
+mkBroadcastP = do
+  chan <- newBroadcastTChanIO
+  return (sendToStore chan, recvFromStore chan)
+  where
+    sendToStore :: TChan a -> Consumer a IO ()
+    sendToStore chan = forever $ do
+      value <- await
+      liftIO . atomically $ writeTChan chan value
+
+    -- Monad will be forked when new outputs connect
+    recvFromStore :: TChan a -> Producer a IO ()
+    recvFromStore chan = do
+      outputChan <- liftIO . atomically $ dupTChan chan
+      forever $ yield =<< (liftIO . atomically $ readTChan outputChan)
+
+-- |Creates a pair of consumer and producer. Both can be used multiple times in parallel.
+-- |All values send to a consumer will be sent to all currently running producers.
+-- |When running a new producer it will immediateley receive the latest value that was sent to a consumer.
+mkBroadcastCacheP :: forall a. a -> IO (Consumer a IO (), Producer a IO ())
+mkBroadcastCacheP initialValue = do
+  store <- (,) <$> newTVarIO initialValue <*> newBroadcastTChanIO
+  return (sendToStore store, recvFromStore store)
+  where
+    sendToStore :: (TVar a, TChan a) -> Consumer a IO ()
+    sendToStore (var, chan) = forever $ do
+      value <- await
+      liftIO . atomically $ do
+        writeTVar var value
+        writeTChan chan value
+
+    -- Monad will be forked when new outputs connect
+    recvFromStore :: (TVar a, TChan a) -> Producer a IO ()
+    recvFromStore (var, chan) = do
+      (outputChan, value) <- liftIO . atomically $ do
+        value <- readTVar var
+        outputChan <- dupTChan chan
+        return (outputChan, value)
+
+      yield value
+
+      forever $ yield =<< (liftIO . atomically $ readTChan outputChan)

test/Spec.hs → qbar/test/Spec.hs

+import Prelude
+
 main :: IO ()
 main = putStrLn "Test suite not yet implemented"

shell.nix

-{ pkgs ? import <nixpkgs> {} }:
-
-pkgs.mkShell {
-  buildInputs = with pkgs; [
-    stack
-    zsh
-    jq
-  ];
-}

src/QBar/Blocks.hs

-module QBar.Blocks (
-  module QBar.Blocks.Battery,
-  module QBar.Blocks.Date
-) where
-
-
-import QBar.Blocks.Battery
-import QBar.Blocks.Date

src/QBar/Cli.hs

-{-# LANGUAGE ApplicativeDo #-}
-
-module QBar.Cli where
-
-import qualified Data.Text as T
-import Options.Applicative
-
-data BarCommand = BarServer | DefaultTheme | RainbowTheme
-
-barCommandParser :: Parser BarCommand
-barCommandParser = hsubparser
-  ( command "server" (info (pure BarServer) (progDesc "Start a new qbar server. Should be called by swaybar, i3bar or or another i3bar-protocol compatible host process.")) <>
-    command "default" (info (pure DefaultTheme) (progDesc "Send a message to a running qbar server.")) <>
-    command "rainbow" (info (pure RainbowTheme) (progDesc "Send a message to a running qbar server."))
-  )
-
-data MainOptions = MainOptions {
-  verbose :: Bool,
-  indicator :: Bool,
-  socketLocation :: Maybe T.Text,
-  barCommand :: BarCommand
-}
-
-mainOptionsParser :: Parser MainOptions
-mainOptionsParser = do
-  verbose <- switch $ long "verbose" <> short 'v' <> help "Print more diagnostic output to stderr (including a copy of every bar update)."
-  indicator <- switch $ long "indicator" <> short 'i' <> help "Show render indicator."
-  socketLocation <- optional $ strOption $ long "socket" <> short 's' <> metavar "SOCKET" <> help "Control socket location. By default determined by WAYLAND_SOCKET location."
-  barCommand <- barCommandParser
-  return MainOptions {verbose, indicator, socketLocation, barCommand}
-
-parser :: ParserInfo MainOptions
-parser = info (mainOptionsParser <**> helper)
-  (fullDesc <> header "qbar - queezles {i3,sway}bar infrastructure")
-
-parserPrefs :: ParserPrefs
-parserPrefs = prefs showHelpOnEmpty
-
-parseOptions :: IO MainOptions
-parseOptions = customExecParser parserPrefs parser
\ No newline at end of file

src/QBar/ControlSocket.hs

-{-# LANGUAGE OverloadedStrings #-}
-{-# LANGUAGE TemplateHaskell #-}
-
-module QBar.ControlSocket where
-
-import QBar.Cli (MainOptions(..))
-import QBar.Core
-import QBar.BlockOutput
-
-import Control.Exception (handle)
-import Control.Monad (forever, void, when)
-import Control.Monad.STM (atomically)
-import Control.Concurrent (forkFinally)
-import Control.Concurrent.Async
-import Control.Concurrent.STM.TChan (TChan, writeTChan)
-import Data.Aeson.TH
-import Data.ByteString (ByteString)
-import System.FilePath ((</>))
-import System.IO
-import Data.Either (either)
-import Data.Maybe (maybe)
-import Data.Text.Lazy (Text, pack)
-import qualified Data.Text as T
-import qualified Data.Text.Lazy as TL
-import Network.Socket
-import Pipes
-import Pipes.Parse
-import Pipes.Aeson (decode, DecodingError)
-import Pipes.Aeson.Unchecked (encode)
-import Pipes.Network.TCP (fromSocket, toSocket)
-import System.Directory (removeFile, doesFileExist)
-import System.Environment (getEnv)
-
-type CommandChan = TChan Command
-
-data Command = SetTheme T.Text
-  | Block
-  deriving Show
-
-data SocketResponse = Success | Error Text
-  deriving Show
-
-$(deriveJSON defaultOptions ''Command)
-$(deriveJSON defaultOptions ''SocketResponse)
-
-ipcSocketAddress :: MainOptions -> IO FilePath
-ipcSocketAddress MainOptions{socketLocation} = maybe defaultSocketPath (return . T.unpack) socketLocation
-  where
-    defaultSocketPath :: IO FilePath
-    defaultSocketPath = do
-      waylandSocketPath' <- waylandSocketPath
-      maybe (maybe headlessSocketPath return =<< i3SocketPath) return waylandSocketPath'
-      where
-        waylandSocketPath :: IO (Maybe FilePath)
-        waylandSocketPath = handleEnvError $ do
-          xdgRuntimeDir <- getEnv "XDG_RUNTIME_DIR"
-          waylandDisplay <- getEnv "WAYLAND_DISPLAY"
-          return $ xdgRuntimeDir </> waylandDisplay <> "-qbar"
-        i3SocketPath :: IO (Maybe FilePath)
-        i3SocketPath = handleEnvError $ do
-          i3SocketPath' <- getEnv "I3_SOCKET_PATH"
-          return $ i3SocketPath' <> "-qbar"
-        headlessSocketPath :: IO FilePath
-        headlessSocketPath = do
-          xdgRuntimeDir <- getEnv "XDG_RUNTIME_DIR"
-          return $ xdgRuntimeDir </> "qbar"
-    handleEnvError :: IO FilePath -> IO (Maybe FilePath)
-    handleEnvError = handle (const $ return Nothing :: IOError -> IO (Maybe FilePath)) . fmap Just
-
-sendIpc :: MainOptions -> Command -> IO ()
-sendIpc options@MainOptions{verbose} request = do
-  socketPath <- ipcSocketAddress options
-  sock <- socket AF_UNIX Stream defaultProtocol
-  connect sock $ SockAddrUnix socketPath
-  runEffect $ encode request >-> toSocket sock
-
-  decodeResult <- evalStateT decode $ fromSocket sock 4096
-  maybe exitEmptyStream (either exitInvalidResult showResponse) decodeResult
-  where
-    exitEmptyStream :: IO ()
-    exitEmptyStream = hPutStrLn stderr "Empty stream"
-    exitInvalidResult :: DecodingError -> IO ()
-    exitInvalidResult = hPrint stderr
-    showResponse :: SocketResponse -> IO ()
-    showResponse Success = when verbose $ hPutStrLn stderr "Success"
-    showResponse (Error message) = hPrint stderr message
-
-listenUnixSocketAsync :: MainOptions -> CommandChan -> IO (Async ())
-listenUnixSocketAsync options commandChan = async $ listenUnixSocket options commandChan
-
-listenUnixSocket :: MainOptions -> CommandChan -> IO ()
-listenUnixSocket options commandChan = do
-  socketPath <- ipcSocketAddress options
-  hPutStrLn stderr $ "Creating control socket at " <> socketPath
-  socketExists <- doesFileExist socketPath
-  when socketExists $ removeFile socketPath
-  sock <- socket AF_UNIX Stream defaultProtocol
-  setCloseOnExecIfNeeded $ fdSocket sock
-  bind sock (SockAddrUnix socketPath)
-  listen sock 5
-  forever $ do
-    (conn, _) <- accept sock
-    void $ forkFinally (socketHandler conn) (\_ -> close conn)
-  where
-    socketHandler :: Socket -> IO ()
-    socketHandler sock = streamHandler (fromSocket sock 4096) (toSocket sock)
-    streamHandler :: Producer ByteString IO () -> Consumer ByteString IO () -> IO ()
-    streamHandler producer consumer = do
-      (decodeResult, leftovers) <- runStateT decode producer
-      response <- maybe (errorResponse "Empty stream") (either handleError (handleCommand leftovers)) decodeResult
-      runEffect (encode response >-> consumer)
-    handleCommand :: Producer ByteString IO () -> Command -> IO SocketResponse
-    handleCommand _ Block = error "TODO" -- addBlock $ handleBlockStream leftovers
-    handleCommand _ command = do
-      atomically $ writeTChan commandChan command
-      return Success
-    handleError :: DecodingError -> IO SocketResponse
-    handleError = return . Error . pack . show
-    errorResponse :: Text -> IO SocketResponse
-    errorResponse message = return $ Error message
-
-handleBlockStream :: Producer ByteString IO () -> PushBlock
-handleBlockStream producer = do
-  (decodeResult, leftovers) <- liftIO $ runStateT decode producer
-  maybe exitBlock (either (\_ -> exitBlock) (handleParsedBlock leftovers)) decodeResult
-  where
-    handleParsedBlock :: Producer ByteString IO () -> String -> PushBlock
-    handleParsedBlock leftovers update = do
-      updateBlock $ mkBlockOutput . normalText $ TL.pack update
-      handleBlockStream leftovers

src/QBar/Core.hs

-{-# LANGUAGE FlexibleInstances #-}
-{-# LANGUAGE TemplateHaskell #-}
-
-module QBar.Core where
-
-import QBar.BlockOutput
-
-import Control.Concurrent (threadDelay)
-import Control.Concurrent.Async
-import Control.Concurrent.Event as Event
-import Control.Concurrent.MVar
-import Control.Concurrent.STM.TChan (TChan, writeTChan)
-import Control.Exception (IOException)
-import Control.Lens
-import Control.Monad (forever)
-import Control.Monad.Reader (ReaderT, runReaderT, ask)
-import Data.Aeson.TH
-import qualified Data.ByteString.Lazy.Char8 as C8
-import Data.Int (Int64)
-import Data.Maybe (catMaybes)
-import qualified Data.Text.Lazy as T
-import qualified Data.Text.Lazy.Encoding as E
-import qualified Data.Text.Lazy.IO as TIO
-import Pipes
-import Pipes.Concurrent
-import Pipes.Safe (SafeT, catchP, runSafeT)
-import qualified Pipes.Prelude as PP
-import System.Exit
-import System.IO
-import System.Process.Typed (Process, shell, setStdin, setStdout,
-  getStdout, closed, createPipe, readProcessStdout, startProcess, stopProcess)
-
-
-data BlockEvent = Click {
-  name :: T.Text,
-  button :: Int
-} deriving Show
-$(deriveJSON defaultOptions ''BlockEvent)
-
-
-data PushMode = PushMode
-data PullMode = PullMode
-data CachedMode = CachedMode
-
-
-type BlockEventHandler = BlockEvent -> BarIO ()
-
-type BlockState = Maybe (BlockOutput, Maybe BlockEventHandler)
-
-type Block a = Producer BlockState BarIO a
-
-
--- |Block that 'yield's an update whenever the block should be changed
-type PushBlock = Block PushMode
--- |Block that generates an update on 'yield'. Should only be pulled when an update is required.
-type PullBlock = Block PullMode
--- |Cached block. Always 'yield's the latest update, so it should only be pulled when the bar is rendered.
-type CachedBlock = Block CachedMode
-
-class IsCachableBlock a where
-  toCachedBlock :: a -> CachedBlock
-
-instance IsCachableBlock PushBlock where
-  toCachedBlock = cachePushBlock
-instance IsCachableBlock CachedBlock where
-  toCachedBlock = id
-
-class IsBlockMode a where
-  exitBlock :: Block a
-instance IsBlockMode PushMode where
-  exitBlock = return PushMode
-instance IsBlockMode PullMode where
-  exitBlock = return PullMode
-instance IsBlockMode CachedMode where
-  exitBlock = return CachedMode
-
-
-type BarIO = SafeT (ReaderT Bar IO)
-
-data Bar = Bar {
-  requestBarUpdate :: IO (),
-  newBlockChan :: TChan CachedBlock
-}
-
-
-data BarUpdateChannel = BarUpdateChannel (IO ())
-type BarUpdateEvent = Event.Event
-
-
-class MonadBarIO m where
-  askBar :: m Bar
-instance MonadBarIO BarIO where
-  askBar = lift ask
-instance MonadBarIO (Proxy a' a b' b BarIO) where
-  askBar = lift askBar
-
-
-mkBlockState :: BlockOutput -> BlockState
-mkBlockState blockOutput = Just (blockOutput, Nothing)
-
-updateBlock :: BlockOutput -> Block ()
-updateBlock blockOutput = yield $ Just (blockOutput, Nothing)
-
-updateBlock' :: BlockEventHandler -> BlockOutput -> Block ()
-updateBlock' blockEventHandler blockOutput = yield $ Just (blockOutput, Just blockEventHandler)
-
-updateEventHandler :: BlockEventHandler -> BlockState -> BlockState
-updateEventHandler _ Nothing = Nothing
-updateEventHandler eventHandler (Just (blockOutput, _)) = Just (blockOutput, Just eventHandler)
-
-
-runBarIO :: Bar -> BarIO r -> IO r
-runBarIO bar action = runReaderT (runSafeT action) bar
-
-modify :: (BlockOutput -> BlockOutput) -> Pipe BlockState BlockState BarIO r
-modify x = PP.map (over (_Just . _1) x)
-
-autoPadding :: Pipe BlockState BlockState BarIO r
-autoPadding = autoPadding' 0 0
-  where
-    autoPadding' :: Int64 -> Int64 -> Pipe BlockState BlockState BarIO r
-    autoPadding' fullLength shortLength = do
-      maybeBlock <- await
-      case maybeBlock of
-        Just (block, eventHandler) -> do
-          let fullLength' = max fullLength . printedLength $ block^.fullText
-          let shortLength' = max shortLength . printedLength $ block^.shortText._Just
-          yield $ Just (padFullText fullLength' . padShortText shortLength' $ block, eventHandler)
-          autoPadding' fullLength' shortLength'
-        Nothing -> do
-          yield Nothing
-          autoPadding' 0 0
-    padString :: Int64 -> BlockText
-    padString len = normalText . T.take len . T.repeat $ ' '
-    padFullText :: Int64 -> BlockOutput -> BlockOutput
-    padFullText len = over fullText $ \s -> padString (len - printedLength s) <> s
-    padShortText :: Int64 -> BlockOutput -> BlockOutput
-    padShortText len = over (shortText._Just) $ \s -> padString (len - printedLength s) <> s
-
-cacheFromInput :: Input BlockState -> CachedBlock
-cacheFromInput input = CachedMode <$ fromInput input
-
--- | Create a shared interval. Takes a BarUpdateChannel to signal bar updates and an interval (in seconds).Data.Maybe
--- Returns an IO action that can be used to attach blocks to the shared interval and an async that contains a reference to the scheduler thread.
-sharedInterval :: Int -> BarIO (PullBlock -> CachedBlock)
-sharedInterval seconds = do
-  clientsMVar <- liftIO $ newMVar ([] :: [(MVar PullBlock, Output BlockState)])
-
-  startEvent <- liftIO Event.new
-
-  task <- barAsync $ do
-    -- Wait for at least one subscribed client
-    liftIO $ Event.wait startEvent
-    forever $ do
-      liftIO $ threadDelay $ seconds * 1000000
-      -- Updates all client blocks
-      -- If send returns 'False' the clients mailbox has been closed, so it is removed
-      bar <- askBar
-      liftIO $ modifyMVar_ clientsMVar $ fmap catMaybes . mapConcurrently (runBarIO bar . runAndFilterClient)
-      -- Then update the bar
-      updateBar
-
-  liftIO $ link task
-
-  return (addClient startEvent clientsMVar)
-  where
-    runAndFilterClient :: (MVar PullBlock, Output BlockState) -> BarIO (Maybe (MVar PullBlock, Output BlockState))
-    runAndFilterClient client = do
-      result <- runClient client
-      return $ if result then Just client else Nothing
-    runClient :: (MVar PullBlock, Output BlockState) -> BarIO Bool
-    runClient (blockMVar, output) = do
-      bar <- askBar
-      liftIO $ modifyMVar blockMVar $ \blockProducer -> do
-        result <- runReaderT (runSafeT $ next blockProducer) bar
-        case result of
-          Left _ -> return (exitBlock, False)
-          Right (blockState, blockProducer') -> do
-            success <- atomically $ send output $ updateEventHandler (updateClickHandler blockState) blockState
-            if success
-              -- Store new BlockProducer back into MVar
-              then return (blockProducer', True)
-              -- Mailbox is sealed, stop running producer
-              else return (exitBlock, False)
-      where
-        updateClickHandler :: BlockState -> BlockEvent -> BarIO ()
-        updateClickHandler Nothing _ = return ()
-        updateClickHandler (Just (block, _)) _ = do
-          -- Give user feedback that the block is updating
-          let outdatedBlock = invalidateBlock block
-          -- The invalidated block output has no event handler
-          liftIO $ void $ atomically $ send output . Just $ (outdatedBlock, Nothing)
-          -- Notify bar about changed block state to display the feedback
-          updateBar
-          -- Run a normal block update to update the block to the new value
-          void $ runClient (blockMVar, output)
-          -- Notify bar about changed block state, this is usually done by the shared interval handler
-          updateBar
-    addClient :: Event.Event -> MVar [(MVar PullBlock, Output BlockState)] -> PullBlock -> CachedBlock
-    addClient startEvent clientsMVar blockProducer = do
-      -- Spawn the mailbox that preserves the latest block
-      (output, input) <- liftIO $ spawn $ latest Nothing
-
-      blockMVar <- liftIO $ newMVar blockProducer
-
-      -- Generate initial block and send it to the mailbox
-      lift $ void $ runClient (blockMVar, output)
-
-      -- Register the client for regular updates
-      liftIO $ modifyMVar_ clientsMVar $ \ clients -> return ((blockMVar, output):clients)
-
-      -- Start update thread (if not already started)
-      liftIO $ Event.set startEvent
-
-      -- Return a block producer from the mailbox
-      cacheFromInput input
-
-blockScript :: FilePath -> PullBlock
-blockScript path = forever $ updateBlock =<< (lift blockScriptAction)
-  where
-    blockScriptAction :: BarIO BlockOutput
-    blockScriptAction = do
-      -- The exit code is used for i3blocks signaling but ignored here (=not implemented)
-      -- I am trying to replace i3blocks scripts with native haskell blocks, so I do not need it
-      (exitCode, output) <- liftIO $ readProcessStdout $ shell path
-      return $ case exitCode of
-        ExitSuccess -> createScriptBlock False normalImportant output
-        (ExitFailure nr) -> case nr of
-          27 -> createScriptBlock False warnImportant output
-          28 -> createScriptBlock False errorImportant output
-          29 -> createScriptBlock False criticalImportant output
-          30 -> createScriptBlock True normalImportant output
-          31 -> createScriptBlock True warnImportant output
-          32 -> createScriptBlock True errorImportant output
-          33 -> createScriptBlock True criticalImportant output
-          _ -> mkErrorOutput $ "[" <> T.pack (show nr) <> "]"
-    createScriptBlock :: Bool -> Importance -> C8.ByteString -> BlockOutput
-    createScriptBlock active importance output = case map E.decodeUtf8 (C8.lines output) of
-      (text:short:_) -> shortText ?~ normalText short $ createScriptBlock' active importance text
-      (text:_) -> createScriptBlock' active importance text
-      [] -> createScriptBlock' active importance "-"
-    createScriptBlock' :: Bool -> Importance -> T.Text -> BlockOutput
-    createScriptBlock' active importance text = blockName ?~ T.pack path $ mkBlockOutput $ mkText active importance text
-
-persistentBlockScript :: FilePath -> PushBlock
--- The outer catchP only catches errors that occur during process creation
-persistentBlockScript path = catchP startScriptProcess handleError
-  where
-    handleError :: IOException -> PushBlock
-    handleError e = do
-      updateBlock . mkErrorOutput $ "[" <> T.pack (show e) <> "]"
-      exitBlock
-    handleErrorWithProcess :: (Process i o e) -> IOException -> PushBlock
-    handleErrorWithProcess process e = do
-      stopProcess process
-      handleError e
-    startScriptProcess :: PushBlock
-    startScriptProcess = do
-      let processConfig = setStdin closed $ setStdout createPipe $ shell path
-      process <- startProcess processConfig
-      -- The inner catchP catches errors that happen after the process has been created
-      -- This handler will also make sure the process is stopped
-      catchP (blockFromHandle $ getStdout process) (handleErrorWithProcess process)
-    blockFromHandle :: Handle -> PushBlock
-    blockFromHandle handle = forever $ do
-      line <- liftIO $ TIO.hGetLine handle
-      updateBlock $ mkBlockOutput . normalText $ line
-      lift updateBar
-
-addBlock :: IsCachableBlock a => a -> BarIO ()
-addBlock block = do
-  newBlockChan' <- newBlockChan <$> askBar
-  liftIO $ atomically $ writeTChan newBlockChan' $ toCachedBlock block
-
-updateBar :: BarIO ()
-updateBar = liftIO =<< requestBarUpdate <$> askBar
-
-updateBar' :: Bar -> IO ()
-updateBar' bar = runBarIO bar updateBar
-
-barAsync :: BarIO a -> BarIO (Async a)
-barAsync action = do
-  bar <- askBar
-  liftIO $ async $ runBarIO bar action
-
-cachePushBlock :: PushBlock -> CachedBlock
-cachePushBlock pushBlock = lift (next pushBlock) >>= either (const exitBlock) withInitialBlock
-  where
-    withInitialBlock :: (BlockState, PushBlock) -> CachedBlock
-    withInitialBlock (initialBlockOutput, pushBlock') = do
-      (output, input, seal) <- liftIO $ spawn' $ latest $ initialBlockOutput
-      -- The async could be used to stop the block later, but for now we are just linking it to catch exceptions
-      task <- lift $ barAsync (sendProducerToMailbox output seal pushBlock')
-      liftIO $ link task
-      terminateOnMaybe $ fromInput input
-    sendProducerToMailbox :: Output BlockState -> STM () -> PushBlock -> BarIO ()
-    sendProducerToMailbox output seal pushBlock' = do
-      -- Send push block output to mailbox until it terminates
-      void $ runEffect $ for pushBlock' (sendOutputToMailbox output)
-      -- Then clear the block and seal the mailbox
-      liftIO $ atomically $ void $ send output Nothing
-      updateBar
-      liftIO $ atomically seal
-    sendOutputToMailbox :: Output BlockState -> BlockState -> Effect BarIO ()
-    sendOutputToMailbox output blockOutput = do
-      -- The void is discarding the boolean result that indicates if the mailbox is sealed
-      -- This is ok because a cached block is never sealed from the receiving side
-      liftIO $ atomically $ void $ send output $ blockOutput
-      lift updateBar
-    terminateOnMaybe :: Producer BlockState BarIO () -> Producer BlockState BarIO CachedMode
-    terminateOnMaybe p = do
-      eitherMaybeValue <- lift $ next p
-      case eitherMaybeValue of
-        Right (Just value, newP) -> yield (Just value) >> terminateOnMaybe newP
-        _ -> exitBlock

src/QBar/DefaultConfig.hs

-module QBar.DefaultConfig where
-
-import QBar.Blocks
-import QBar.BlockOutput
-import QBar.Core
-
-import Pipes
-
-import Control.Lens
-
-blockLocation :: String -> FilePath
-blockLocation name = "~/.config/qbar/blocks/" <> name
-
-generateDefaultBarConfig :: BarIO ()
-generateDefaultBarConfig = do
-  systemInfoInterval <- sharedInterval 10
-
-  let todo = systemInfoInterval (blockScript $ blockLocation "todo")
-  let wifi = systemInfoInterval (blockScript $ blockLocation "wifi2") >-> modify (addIcon "📡\xFE0E")
-  let networkEnvironment = systemInfoInterval (blockScript $ blockLocation "network-environment")
-  let cpu = systemInfoInterval (blockScript $ blockLocation "cpu_usage") >-> modify ((blockName ?~ "cpu") . addIcon "💻\xFE0E") >-> autoPadding
-  let ram = systemInfoInterval (blockScript $ blockLocation "memory") >-> modify (addIcon "🐏\xFE0E") >-> autoPadding
-  let temperature = systemInfoInterval (blockScript $ blockLocation "temperature") >-> autoPadding
-  let volumeBlock = persistentBlockScript $ blockLocation "volume-pulseaudio -S -F3"
-  let battery = systemInfoInterval $ batteryBlock >-> modify (blockName ?~ "battery")
-
-  addBlock dateBlock
-  addBlock battery
-  addBlock volumeBlock
-  addBlock temperature
-  addBlock ram
-  addBlock cpu
-  addBlock networkEnvironment
-  addBlock wifi
-  addBlock todo

src/QBar/Pango.hs

-{-# LANGUAGE OverloadedStrings #-}
-
-module QBar.Pango (Pango, parsePango, removeFormatting) where
-
-import Control.Applicative ((<|>))
-import Control.Monad (void)
-import qualified Data.Text.Lazy as T
-import Data.Attoparsec.Text.Lazy as A
-
-data Pango = PText T.Text
-  | PTag T.Text [(T.Text, T.Text)] Pango
-  | PList [Pango]
-  deriving Show
-
-pList :: [Pango] -> Pango
-pList [one] = one
-pList more = PList more
-
-pangoParser :: Parser Pango
-pangoParser = pList <$> many' (choice [normalTextParser, tagParser])
-  where
-    normalTextParser :: Parser Pango
-    normalTextParser  = PText . T.fromStrict <$> A.takeWhile1 (notInClass "<>")
-
-    tagParser :: Parser Pango
-    tagParser = do
-      tagName <- char '<' >> identifier
-      attributes <- many' $ do
-        space >> skipSpace
-        attributeName <- identifier
-        void $ char '='
-        value <- char '\'' *> many' (notChar '\'') <* char '\''
-          <|> char '"' *> many' (notChar '"') <* char '"'
-        return (attributeName, T.pack value)
-      void $ char '>'
-      content <- pangoParser
-      -- close tag
-      void $ string $ T.toStrict $ "</" <> tagName <> ">"
-      return $ PTag tagName attributes content
-
-    identifier :: Parser T.Text
-    identifier = T.pack <$> many1 (letter <|> digit)
-
-parsePango :: T.Text -> Either String Pango
-parsePango text = parseOnly (pangoParser <* endOfInput) (T.toStrict text)
-
-removeFormatting :: Pango -> T.Text
-removeFormatting (PText text) = text
-removeFormatting (PTag _ _ child) = removeFormatting child
-removeFormatting (PList list) = mconcat $ map removeFormatting list
\ No newline at end of file

src/QBar/Server.hs

-{-# LANGUAGE DuplicateRecordFields #-}
-
-module QBar.Server where
-
-import QBar.BlockOutput
-import QBar.Core
-import QBar.Cli
-import QBar.ControlSocket
-import QBar.Host
-import QBar.Theme
-
-import Control.Monad (forever, when, unless, forM_)
--- import Control.Concurrent.Async
-import Control.Concurrent.STM.TChan (newTChanIO)
-import Data.Aeson (encode, decode, ToJSON, toJSON, object, (.=))
-import Data.ByteString.Lazy (hPut)
-import qualified Data.ByteString.Char8 as BSSC8
-import qualified Data.ByteString.Lazy as BS
-import qualified Data.ByteString.Lazy.Char8 as C8
-import Data.Maybe (fromMaybe)
-import qualified Data.Text.Lazy as T
-import Pipes
-import System.IO (stdin, stdout, stderr, hFlush)
-import Control.Lens hiding (each, (.=))
-
-renderIndicator :: CachedBlock
--- Using 'cachedBlock' is a hack to actually get the block to update on every bar update (by doing this it will not get a cache later in the pipeline).
-renderIndicator = forever $ each $ map (mkBlockState . mkBlockOutput . normalText) ["/", "-", "\\", "|"]
-
-data RenderBlock = RenderBlock {
-  renderBlockFullText :: PangoText,
-  renderBlockShortText :: Maybe PangoText,
-  renderBlockName :: Maybe T.Text
-} deriving(Show)
-instance ToJSON RenderBlock where
-  toJSON RenderBlock{renderBlockFullText, renderBlockShortText, renderBlockName} = object $
-    fullText' <> shortText' <> blockName' <> pango'
-    where
-      fullText' = [ "full_text" .= renderBlockFullText ]
-      shortText' = fromMaybe (\s -> ["short_text" .= s]) mempty renderBlockShortText
-      blockName' = fromMaybe (\s -> ["name" .= s]) mempty renderBlockName
-      pango' = [ "markup" .= ("pango" :: T.Text) ]
-
-
--- |A consumer that accepts lists of 'BlockOutput' and renders them to stdout using the {sway,i3}bar-protocol.
-swayBarOutput :: MainOptions -> Consumer [BlockOutput] BarIO ()
-swayBarOutput MainOptions{verbose} = do
-  -- Output header
-  liftIO $ do
-    putStrLn "{\"version\":1,\"click_events\":true}"
-    putStrLn "["
-
-  swayBarOutput'
-  where
-    swayBarOutput' :: Consumer [BlockOutput] BarIO ()
-    swayBarOutput' = do
-      blocks <- await
-
-      let encodedOutput = encodeOutput blocks
-
-      liftIO $ do
-        hPut stdout encodedOutput
-        putStrLn ","
-        hFlush stdout
-        -- Echo output to stderr when verbose flag is set
-        when verbose $ do
-          hPut stderr encodedOutput
-          hPut stderr "\n"
-          hFlush stderr
-
-      swayBarOutput'
-    encodeOutput :: [BlockOutput] -> BS.ByteString
-    encodeOutput bs = encode $ zipWith encodeBlock bs $ defaultTheme bs
-    encodeBlock :: BlockOutput -> (T.Text, Maybe T.Text) -> RenderBlock
-    encodeBlock b (fullText', shortText') = RenderBlock fullText' shortText' (b ^. blockName)
-
--- |A producer that reads swaybar/i3bar-input events from stdin and emits them as 'BlockEvent's.
-swayBarInput :: MainOptions -> Producer BlockEvent BarIO ()
-swayBarInput MainOptions{verbose} = swayBarInput'
-  where
-    swayBarInput' :: Producer BlockEvent BarIO ()
-    swayBarInput' = do
-      line <- liftIO $ BSSC8.hGetLine stdin
-
-      unless (line == "[") $ do
-        -- Echo input to stderr when verbose flag is set
-        when verbose $ liftIO $ do
-          liftIO $ BSSC8.hPutStrLn stderr line
-          hFlush stderr
-
-        let maybeBlockEvent = decode $ removeComma $ BS.fromStrict line
-        forM_ maybeBlockEvent yield
-
-      swayBarInput'
-
-    removeComma :: C8.ByteString -> C8.ByteString
-    removeComma line
-      | C8.head line == ',' = C8.tail line
-      | C8.last line == ',' = C8.init line
-      | otherwise = line
-
-
-runBarServer :: BarIO () -> MainOptions -> IO ()
-runBarServer defaultBarConfig options = runBarHost barServer (swayBarInput options)
-  where
-    barServer :: Consumer [BlockOutput] BarIO ()
-    barServer = do
-      -- Load blocks
-      lift $ do
-        when (indicator options) $ addBlock renderIndicator
-        defaultBarConfig
-
-      -- Create control socket
-      -- commandChan <- liftIO createCommandChan
-      -- controlSocketAsync <- liftIO $ listenUnixSocketAsync options commandChan
-      -- liftIO $ link controlSocketAsync
-
-      -- bar <- askBar
-
-      -- Update bar on control socket messages
-      -- socketUpdateAsync <- liftIO $ async $ forever $ do
-      --   -- command <- atomically $ readTChan commandChan
-      --   void $ error "TODO"
-      --   updateBar' bar
-      -- liftIO $ link socketUpdateAsync
-
-      swayBarOutput options
-
-createCommandChan :: IO CommandChan
-createCommandChan = newTChanIO
-
--- |Entry point.
-runQBar :: BarIO () -> MainOptions -> IO ()
-runQBar barConfiguration options@MainOptions{barCommand} = runCommand barCommand
-  where
-    runCommand BarServer = runBarServer barConfiguration options
-    runCommand DefaultTheme = sendIpc options $ SetTheme "default"
-    runCommand RainbowTheme = sendIpc options $ SetTheme "rainbow"

src/QBar/Theme.hs

-module QBar.Theme where
-
-import QBar.BlockOutput
-
-import Control.Lens ((^.), (.~))
-import Control.Monad.State.Lazy (State, evalState, get, put)
-import Data.Colour.RGBSpace
-import Data.Colour.RGBSpace.HSV (hsv)
-import qualified Data.Text.Lazy as T
-import Numeric (showHex)
-
-
-data Color = ColorRGB (RGB Double) | ColorRGBA (RGB Double) Double
-
-
-type Theme = [BlockOutput] -> [(PangoText, Maybe PangoText)]
-type SimplifiedTheme = Bool -> Importance -> (Color, Maybe Color)
-type AnimatedTheme = Double -> Theme
-
-
-mkTheme :: SimplifiedTheme -> Theme
-mkTheme theming' = map themeBlock
-  where
-    themeBlock :: BlockOutput -> (PangoText, Maybe PangoText)
-    themeBlock block = (fullText', shortText')
-      where
-        theming :: SimplifiedTheme
-        theming
-          | block ^. invalid = invalidSimplifiedTheme
-          | otherwise = theming'
-        fullText' :: PangoText
-        fullText' = themeBlockText theming $ block ^. fullText
-        shortText' :: Maybe PangoText
-        shortText' = themeBlockText theming <$> block ^. shortText
-    themeBlockText :: SimplifiedTheme -> BlockText -> PangoText
-    themeBlockText theming (BlockText b) = foldMap (themeSegment theming) b
-    themeSegment :: SimplifiedTheme -> BlockTextSegment -> PangoText
-    themeSegment theming BlockTextSegment {active, importance, text} = (coloredText' $ theming active importance) text
-    themeSegment _ (PangoTextSegment text) = text
-
-
-invalidColor :: Color
-invalidColor = ColorRGBA (RGB (0x96 / 255) (0x98 / 255) (0x96 / 255)) (0x77 / 255)
-
-
-invalidSimplifiedTheme :: SimplifiedTheme
-invalidSimplifiedTheme _ _ = (invalidColor, Nothing)
-
-
-invalidTheme :: Theme
-invalidTheme = mkTheme invalidSimplifiedTheme
-
-
-defaultTheme :: Theme
-defaultTheme = mkTheme defaultTheme'
-  where
-    defaultTheme' :: SimplifiedTheme
-    defaultTheme' active importance
-      | isCritical importance, active = (ColorRGB (RGB 0 0 0), Just $ ColorRGB (RGB 1 0 0))
-      | isCritical importance         = (ColorRGB (RGB 0.8 0.15 0.15), Nothing)
-      | isError importance, active    = (ColorRGB (RGB 1 0.3 0), Nothing)
-      | isError importance            = (ColorRGB (RGB 0.7 0.35 0.2), Nothing)
-      | isWarning importance,active   = (ColorRGB (RGB 1 0.9 0), Nothing)
-      | isWarning importance          = (ColorRGB (RGB 0.6 0.6 0), Nothing)
-      | otherwise, active             = (ColorRGB (RGB 1 1 1), Nothing)
-      | otherwise                     = (ColorRGB (RGB (0x96 / 255) (0x98 / 255) (0x96 / 255)), Nothing)
-
-
-rainbowTheme :: Double -> [BlockOutput] -> [BlockOutput]
-rainbowTheme time blocks = reverse $ evalState (mapM rainbowBlock $ reverse blocks) 0
-  where
-    rainbowBlock :: BlockOutput -> State Integer BlockOutput
-    rainbowBlock block = do
-      let text = rawText $ block ^. fullText
-      let chars = T.unpack . T.reverse $ text
-      coloredChars <- mapM rainbowChar chars
-      let rainbowText = T.concat . reverse $ coloredChars
-      return $ fullText .~ pangoText rainbowText $ block
-    rainbowChar :: Char -> State Integer T.Text
-    rainbowChar char = do
-      color <- nextRainbowColor
-      return $ coloredText color $ T.singleton char
-    nextRainbowColor :: State Integer Color
-    -- nextRainbowColor = state $ \index -> (rainbowColor (fromInteger index), index + 1)
-    nextRainbowColor = do
-      index <- get
-      put $ index + 1
-      return $ rainbowColor (fromInteger index + time * 10)
-    rainbowColor :: Double -> Color
-    rainbowColor position =
-      let hue' = position * 3
-          color = hsv hue' 0.8 1.0
-      in ColorRGB color
-
-
-coloredText :: Color -> T.Text -> PangoText
-coloredText color text = "<span color='" <> pangoColor color <> "'>" <> text <> "</span>"
-
-coloredText' :: (Color, Maybe Color) -> T.Text -> PangoText
-coloredText' (foreground, Nothing) text = "<span color='" <> pangoColor foreground <> "'>" <> text <> "</span>"
-coloredText' (foreground, Just background) text = "<span color='" <> pangoColor foreground <> "' background='" <> pangoColor background <> "'>" <> text <> "</span>"
-
-
-pangoColor :: Color -> T.Text
-pangoColor = pangoColor'
-  where
-    pangoColor' :: Color -> T.Text
-    pangoColor' (ColorRGB rgb) = pangoRGB rgb
-    pangoColor' (ColorRGBA rgb a) = pangoRGB rgb <> hexColorComponent a
-
-    pangoRGB :: RGB Double -> T.Text
-    pangoRGB (RGB r g b) =
-      let r' = hexColorComponent r
-          g' = hexColorComponent g
-          b' = hexColorComponent b
-      in "#" <> r' <> g' <> b'
-    hexColorComponent :: Double -> T.Text
-    hexColorComponent val = paddedHexComponent $ T.pack $ showHex (max 0 $ min 255 (truncate (val * 255) :: Int)) ""
-    paddedHexComponent :: T.Text -> T.Text
-    paddedHexComponent hex =
-      let len = 2 - T.length hex
-          padding = if len == 1 then "0" else ""
-      in padding <> hex

src/QBar/Time.hs

-module QBar.Time (sleepUntil, nextMinute) where
-
-import Control.Concurrent (threadDelay)
-import Control.Monad (when)
-import Data.Time.Clock (UTCTime, getCurrentTime, diffUTCTime, utctDayTime)
-
-sleepUntil :: UTCTime -> IO ()
-sleepUntil time = do
-  now <- getCurrentTime
-  let timeUntil = diffUTCTime time now
-  when (timeUntil > 0) $
-    if timeUntil > 1
-      then threadDelay 1000000 >> sleepUntil time
-      else threadDelay $ ceiling $ toRational timeUntil * 1000000
-
-nextMinute :: IO UTCTime
-nextMinute = do
-  now <- getCurrentTime
-  let dayTime = utctDayTime now
-  let daySeconds = floor dayTime
-  let dayMinute = daySeconds `div` 60
-  return now {
-    utctDayTime = fromInteger $ (dayMinute + 1) * 60
-  }
\ No newline at end of file

stack.yaml

-# This file was automatically generated by 'stack init'
-#
-# Some commonly used options have been documented as comments in this file.
-# For advanced use and comprehensive documentation of the format, please see:
-# https://docs.haskellstack.org/en/stable/yaml_configuration/
-
-# Resolver to choose a 'specific' stackage snapshot or a compiler version.
-# A snapshot resolver dictates the compiler version and the set of packages
-# to be used for project dependencies. For example:
-#
-# resolver: lts-3.5
-# resolver: nightly-2015-09-21
-# resolver: ghc-7.10.2
-#
-# The location of a snapshot can be provided as a file or url. Stack assumes
-# a snapshot provided as a file might change, whereas a url resource does not.
-#
-# resolver: ./custom-snapshot.yaml
-# resolver: https://example.com/snapshots/2018-01-01.yaml
-resolver: lts-14.20
-
-# User packages to be built.
-# Various formats can be used as shown in the example below.
-#
-# packages:
-# - some-directory
-# - https://example.com/foo/bar/baz-0.0.2.tar.gz
-# - location:
-#    git: https://github.com/commercialhaskell/stack.git
-#    commit: e7b331f14bcffb8367cd58fbfc8b40ec7642100a
-# - location: https://github.com/commercialhaskell/stack/commit/e7b331f14bcffb8367cd58fbfc8b40ec7642100a
-#  subdirs:
-#  - auto-update
-#  - wai
-packages:
-- .
-# Dependency packages to be pulled from upstream that are not in the resolver
-# using the same syntax as the packages field.
-# (e.g., acme-missiles-0.3)
-# extra-deps: []
-
-# Disable pure nix-shell environment on NixOS, because access to XDG_RUNTIME_DIR is needed for the control socket
-nix:
-  pure: false
-
-# Override default flag values for local packages and extra-deps
-# flags: {}
-
-# Extra package databases containing global packages
-# extra-package-dbs: []
-
-# Control whether we use the GHC we find on the path
-# system-ghc: true
-#
-# Require a specific version of stack, using version ranges
-# require-stack-version: -any # Default
-# require-stack-version: ">=1.9"
-#
-# Override the architecture used by stack, especially useful on Windows
-# arch: i386
-# arch: x86_64
-#
-# Extra directories used by stack for building
-# extra-include-dirs: [/path/to/dir]
-# extra-lib-dirs: [/path/to/dir]
-#
-# Allow a newer minor version of GHC than the snapshot specifies
-# compiler-check: newer-minor